Eingabeoptionen beschränken

Mit einem Funktionsbaustein können Sie erzwingen, dass bei der Werteselektion nur von Ihnen vorgegebene Optionen zulässig sind. In diesem Fall zeigen wir Ihnen, wie Sie die Eingabe auf Einzelwerte beschränken können. Das bedeutet, dass der Anwender nur die Option “EQ” zur Selektion angezeigt bekommt.

REPORT zz_sel_restriction.
*---------------------------------------------------------------------*
* Nur bestimmte Optionen bei der Auswahl zulassen
* In diesem Fall: Nur Einzelwerte zulassen
*---------------------------------------------------------------------*
TYPE-POOLS sscr.
DATA h_matnr    TYPE matnr.
DATA t_restrict TYPE sscr_restrict.
DATA l_ass      TYPE sscr_ass.
DATA l_opt      TYPE sscr_opt_list.

*-- Selektionsbild
SELECT-OPTIONS matnr FOR h_matnr NO INTERVALS.
INITIALIZATION.
*-- OptionsTable bauen
CLEAR l_opt.
l_opt-name       = 'OL_MATNR'.
l_opt-options-eq = 'X'.  "Nur Einzelwerte zulassen
APPEND l_opt TO t_restrict-opt_list_tab.

*-- Zuordnung zu den Selektionsfeldern
CLEAR l_ass.
MOVE: 'S'         TO l_ass-kind,
      'MATNR'     TO l_ass-name,
      'I'         TO l_ass-sg_main,
      'OL_MATNR'  TO l_ass-op_main.
APPEND l_ass TO t_restrict-ass_tab.

*-- Restriktionen aktivieren
CALL FUNCTION 'SELECT_OPTIONS_RESTRICT'
  EXPORTING
    restriction            = t_restrict
  EXCEPTIONS
    too_late               = 1
    repeated               = 2
    selopt_without_options = 3
    selopt_without_signs   = 4
    invalid_sign           = 5
    empty_option_list      = 6
    invalid_kind           = 7
    repeated_kind_a        = 8
    OTHERS                 = 9.
IF sy-subrc <> 0.
"Fehler
ENDIF.

• Über
• Letzte Artikel

Enno Wulff

SAP Berater & Entwickler bei Inwerken AG

Moin Moin! Ich heiße Enno und bin der Erfinder, Redakteur und Trickser im Tricktresor. Die Artikel im Tricktresor sollen Euch das Leben einfacher machen und dienen mir als Gedächtnisstütze. Denn an vieles, was ich einmal heraus gefunden habe, kann ich mich später nicht mehr erinnern und suche erneut. Dagegen hilft der Tricktresor. Viel Spaß!

Letzte Artikel von Enno Wulff (Alle anzeigen)

• Interview mit Björn Schulz (Software-Heroes.com) - 3. September 2024
• Daten aus ALV ermitteln - 3. September 2024
• So lange es den SAPGUI noch gibt… - 27. Juni 2024