TABLES vbak.

DATA gv_eins TYPE c VALUE 'X'.
DATA gv_zwei TYPE c.
DATA gv_drei TYPE c.


START-OF-SELECTION.

  CALL SCREEN 100.

*&---------------------------------------------------------------------*
*&      Module  exit_command_0100  INPUT
*&---------------------------------------------------------------------*
MODULE exit_command_0100 INPUT.

  PERFORM exit_command_0100.

ENDMODULE.                 " exit_command_0100  INPUT


*&---------------------------------------------------------------------*
*&      Form  exit_command_0100
*&---------------------------------------------------------------------*
FORM exit_command_0100.

  DATA dynnr             TYPE sydynnr.
  DATA repid             TYPE syrepid.
  DATA t_fields          TYPE STANDARD TABLE OF dynpread WITH NON-UNIQUE DEFAULT KEY.
  DATA wa_field          LIKE LINE OF t_fields.
  DATA lv_field_type     TYPE c.
  FIELD-SYMBOLS: <field> TYPE ANY.

  CASE sy-ucomm.
    WHEN 'EXIT'.

      SET SCREEN 0. LEAVE SCREEN.

    WHEN 'RB'.

      dynnr = sy-dynnr.
      repid = sy-repid.

      CALL FUNCTION 'DYNP_VALUES_READ'
        EXPORTING
          dyname                   = repid
          dynumb                   = dynnr
          request                  = 'A'
          perform_conversion_exits = ' '
          perform_input_conversion = ' '
        TABLES
          dynpfields               = t_fields
        EXCEPTIONS
          OTHERS                   = 11.
      LOOP AT t_fields INTO wa_field.
        ASSIGN (wa_field-fieldname) TO <field>.
        CHECK sy-subrc = 0.
        DESCRIBE FIELD <field> TYPE lv_field_type.
        CASE lv_field_type.
          WHEN 'P'.
*** Packed
            CALL FUNCTION 'RS_CONV_EX_2_IN_DTEL'
              EXPORTING
                input_external  = wa_field-fieldvalue
                dtel            = 'NETWR'
              IMPORTING
                output_internal = <field>
              EXCEPTIONS
                OTHERS          = 21.

          WHEN 'T'.
*** Time
            CALL FUNCTION 'CONVERSION_EXIT_TIMLO_INPUT'
              EXPORTING
                input       = wa_field-fieldvalue
              IMPORTING
                output      = <field>
              EXCEPTIONS
                wrong_input = 1
                OTHERS      = 2.


          WHEN 'D'.
*** Date
            CALL FUNCTION 'CONVERSION_EXIT_SDATE_INPUT'
              EXPORTING
                input  = wa_field-fieldvalue
              IMPORTING
                output = <field>.

          WHEN OTHERS.
            <field> = wa_field-fieldvalue.
        ENDCASE.
      ENDLOOP.
      LEAVE SCREEN.
  ENDCASE.

ENDFORM.                    "exit_command_0100

*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
MODULE user_command_0100 INPUT.


ENDMODULE.                 " USER_COMMAND_0100  INPUT

*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.

  SET PF-STATUS '100'.

  LOOP AT SCREEN.
    CASE screen-group1.
      WHEN 1.
        IF gv_eins <> space.
          screen-required = '1'.
          MODIFY SCREEN.
        ENDIF.

      WHEN 2.
        IF gv_zwei <> space.
          screen-required = '1'.
          MODIFY SCREEN.
        ENDIF.

      WHEN 3.
        IF gv_drei <> space.
          screen-required = '1'.
          MODIFY SCREEN.
        ENDIF.

    ENDCASE.
  ENDLOOP.

ENDMODULE.                 " STATUS_0100  OUTPUT